网管联盟论坛 - 共享互助,专助进取

 找回密码
 立即注册

QQ登录

只需一步,快速开始

DBNT云维护 三层集中管理 手机远程深蓝软件微信公众号深蓝防逃费V6(多收费共存/全自动处理)
查看: 1085|回复: 9

[开源] 2345扣量解决【AU3源码】

[复制链接]

992

主题

1万

帖子

1万

积分

超级版主

Rank: 21Rank: 21Rank: 21Rank: 21Rank: 21Rank: 21

终身成就奖

发表于 2016-3-26 15:44:56 | 显示全部楼层 |阅读模式
本帖最后由 the886 于 2017-7-27 01:43 编辑

....被扣了一年多,一直没空理他

可以放到维护通道 开机 运行,支持XP WIN7 等

广告: 推荐使用 DBNT


_WinINet_ClearCache(1)

;===================================
;       0 -  删除所有缓存项
;       1 - 删除cookies
;       2 - 删除URL历史项
;===================================





;===================================
;       0 -  删除所有缓存项
;       1 - 删除cookies
;       2 - 删除URL历史项
;===================================
Func _WinINet_ClearCache($iCacheEntryType = 0)
        _WinINet_Startup()
        Local $avCacheEntry = _WinINet_FindFirstUrlCacheEntry($iCacheEntryType)
        If Not @error Then
                Local $hCacheEntry = $avCacheEntry[0]
                Local $avCacheEntryInfo = $avCacheEntry[1];数组存放数组,$avCacheEntryInfo也是一个数组
                $avCacheEntry = 0
                While Not @error
                        ;ConsoleWrite($avCacheEntryInfo[1] & @CRLF)
                        _WinINet_DeleteUrlCacheEntry($avCacheEntryInfo[1])
                        $avCacheEntryInfo = _WinINet_FindNextUrlCacheEntry($hCacheEntry)
                WEnd
                _WinINet_FindCloseUrlCache($hCacheEntry)
        EndIf
        _WinINet_Shutdown()
EndFunc   ;==>_WinINet_ClearCache


Func _WinINet_FindCloseUrlCache($hUrlCacheEntry)
        ; Make DLL call
        Local $avResult = DllCall($__WinINet_hDLL, _
                        "int", "FindCloseUrlCache", _
                        "ptr", $hUrlCacheEntry _
                        )

        ; Return response
        If @error Or Not $avResult[0] Then Return SetError(1, 0, False)
        Return True
EndFunc   ;==>_WinINet_FindCloseUrlCache

Func _WinINet_Shutdown()
        If Not IsString($__WinINet_hDLL) Then
                DllClose($__WinINet_hDLL)
        EndIf

        $__WinINet_hDLL = $__WinINet_sDLL
EndFunc   ;==>_WinINet_Shutdown

Func _WinINet_FindNextUrlCacheEntry($hUrlCacheEntry)
        ; Set data/structures up
        Local $tCacheEntryInfoSize = DllStructCreate("dword")

        ; (dummy call to get required structure size)
        DllCall($__WinINet_hDLL, _
                        "int", "FindNextUrlCacheEntry" & $WIN32_FTYPE, _
                        "ptr", $hUrlCacheEntry, _
                        "ptr", 0, _
                        "ptr", DllStructGetPtr($tCacheEntryInfoSize) _
                        )
        If @error Then Return SetError(1, 0, 0)

        ; (space slightly overallocated so we don't need to waste time creating the structure twice)
        Local $tCacheEntryInfo = DllStructCreate( _
                        $tagINTERNET_CACHE_ENTRY_INFO & "; " & _
                        "byte[" & (DllStructGetData($tCacheEntryInfoSize, 1) + 1) & "]" _
                        )

        ; Make DLL call
        Local $avResult = DllCall($__WinINet_hDLL, _
                        "int", "FindNextUrlCacheEntry" & $WIN32_FTYPE, _
                        "ptr", $hUrlCacheEntry, _
                        "ptr", DllStructGetPtr($tCacheEntryInfo), _
                        "ptr", DllStructGetPtr($tCacheEntryInfoSize) _
                        )

        ; Return response
        If @error Or Not $avResult[0] Then Return SetError(1, 0, 0)
        Return _WinINet_Struct_InternetCacheEntryInfo_ToArray($tCacheEntryInfo)
EndFunc   ;==>_WinINet_FindNextUrlCacheEntry


Func _WinINet_DeleteUrlCacheEntry($sUrlName)
        ; Make DLL call
        Local $avResult = DllCall($__WinINet_hDLL, _
                        "int", "DeleteUrlCacheEntry" & $WIN32_FTYPE, _
                        $WIN32_TSTR, $sUrlName _
                        )

        ; Return response
        If @error Or $avResult[0] <> 0 Then Return SetError(1, 0, False)
        Return True
EndFunc   ;==>_WinINet_DeleteUrlCacheEntry


Func _WinINet_Startup()
        If IsString($__WinINet_hDLL) Then
                $__WinINet_hDLL = DllOpen($__WinINet_sDLL)
        EndIf

        If (@error Or $__WinINet_hDLL = -1) Then
                _WinINet_Shutdown()
                Return SetError(1, 0, False)
        EndIf

        Return True
EndFunc   ;==>_WinINet_Startup

Func _WinINet_FindFirstUrlCacheEntry($iCacheEntryType = 0)
        ; Set data/structures up
        Local $sUrlSearchPattern = "*.*"
        Switch $iCacheEntryType
                Case 1
                        $sUrlSearchPattern = "cookie:"
                Case 2
                        $sUrlSearchPattern = "visited:"
        EndSwitch

        Local $tCacheEntryInfoSize = DllStructCreate("dword")

        ; (dummy call to get required structure size)
        DllCall($__WinINet_hDLL, _
                        "ptr", "FindFirstUrlCacheEntry" & $WIN32_FTYPE, _
                        $WIN32_TSTR, $sUrlSearchPattern, _
                        "ptr", 0, _
                        "ptr", DllStructGetPtr($tCacheEntryInfoSize) _
                        )
        If @error Then Return SetError(1, 0, 0)

        ; (space slightly overallocated so we don't need to waste time creating the structure twice)
        Local $tCacheEntryInfo = DllStructCreate( _
                        $tagINTERNET_CACHE_ENTRY_INFO & "; " & _
                        "byte[" & (DllStructGetData($tCacheEntryInfoSize, 1) + 1) & "]" _
                        )

        ; Make DLL call
        Local $avResult = DllCall($__WinINet_hDLL, _
                        "ptr", "FindFirstUrlCacheEntry" & $WIN32_FTYPE, _
                        $WIN32_TSTR, $sUrlSearchPattern, _
                        "ptr", DllStructGetPtr($tCacheEntryInfo), _
                        "ptr", DllStructGetPtr($tCacheEntryInfoSize) _
                        )

        ; Return response
        If @error Or Not $avResult[0] Then Return SetError(1, 0, 0)

        Local $avReturn[2] = [$avResult[0], _WinINet_Struct_InternetCacheEntryInfo_ToArray($tCacheEntryInfo)]
        Return $avReturn
EndFunc   ;==>_WinINet_FindFirstUrlCacheEntry


Func _WinINet_Struct_InternetCacheEntryInfo_ToArray(ByRef $tCacheEntryInfo)
        ; We need to "fudge" the length of several members of the $tagINTERNET_CACHE_ENTRY_INFO structure because they are simply
        ; pointers to an area in memory located at the end of the structure. We cannot detect the exact length of the strings short
        ; of looping through the memory looking for a null character by calling DllStructGetData() on a DllStruct created at each
        ; address in memory immediately following the pointer, which is very slow and inefficient. As such, we estimate the maximum
        ; possible size of the buffer instead of getting an exact size, read that much data as Binary, then let
        ; String(BinaryToString()) truncate the string for us.

        Local $avReturn[13], $iPtr, $iStructEnd = Dec(StringTrimLeft(DllStructGetPtr($tCacheEntryInfo), 2)) + DllStructGetSize($tCacheEntryInfo)
        Local $iB2SFlag = $AU3_UNICODE + 1

        ; Cache Entry Type
        $avReturn[0] = DllStructGetData($tCacheEntryInfo, "CacheEntryType")

        ; Source URL
        $iPtr = DllStructGetData($tCacheEntryInfo, "SourceUrlName")
        $avReturn[1] = String(BinaryToString(_WinINet_DllStructReadArray($iPtr, $iStructEnd - Dec(StringTrimLeft($iPtr, 2)), "byte"), $iB2SFlag))

        ; Local File
        $iPtr = DllStructGetData($tCacheEntryInfo, "LocalFileName")
        $avReturn[2] = String(BinaryToString(_WinINet_DllStructReadArray($iPtr, $iStructEnd - Dec(StringTrimLeft($iPtr, 2)), "byte"), $iB2SFlag))

        ; File Extension
        $iPtr = DllStructGetData($tCacheEntryInfo, "FileExtension")
        $avReturn[3] = String(BinaryToString(_WinINet_DllStructReadArray($iPtr, $iStructEnd - Dec(StringTrimLeft($iPtr, 2)), "byte"), $iB2SFlag))

        ; Header Info
        $iPtr = DllStructGetData($tCacheEntryInfo, "HeaderInfo")
        $avReturn[4] = String(BinaryToString(_WinINet_DllStructReadArray($iPtr, $iStructEnd - Dec(StringTrimLeft($iPtr, 2)), "byte"), $iB2SFlag))

        ; Use Count
        $avReturn[5] = DllStructGetData($tCacheEntryInfo, "UseCount")

        ; Hit Rate
        $avReturn[6] = DllStructGetData($tCacheEntryInfo, "HitRate")

        ; Size
        $avReturn[7] = DllStructGetData(DllStructCreate("int64", DllStructGetPtr($tCacheEntryInfo, "Size")), 1)

        ; Expire Time
        $avReturn[8] = DllStructGetData(DllStructCreate("int64", DllStructGetPtr($tCacheEntryInfo, "ExpireTime")), 1)

        ; Last Access Time
        $avReturn[9] = DllStructGetData(DllStructCreate("int64", DllStructGetPtr($tCacheEntryInfo, "LasAccessTime")), 1)

        ; Last Sync Time
        $avReturn[10] = DllStructGetData(DllStructCreate("int64", DllStructGetPtr($tCacheEntryInfo, "LastSyncTime")), 1)

        ; Last Modified Time
        $avReturn[11] = DllStructGetData(DllStructCreate("int64", DllStructGetPtr($tCacheEntryInfo, "LastModifiedTime")), 1)

        ; Reserved / Exempt Delta
        $avReturn[12] = DllStructGetData($tCacheEntryInfo, "ReservedExemptDelta")

        Return $avReturn
EndFunc   ;==>_WinINet_Struct_InternetCacheEntryInfo_ToArray

Func _WinINet_DllStructReadArray($pData, $iLength, $sType = Default)
        If $iLength <= 0 Then Return ""
        If $sType = Default Then $sType = $WIN32_TCHAR
        Return DllStructGetData(DllStructCreate($sType & "[" & $iLength & "]", $pData), 1)
EndFunc   ;==>_WinINet_DllStructReadArray


QQ图片20160326154511.png

2345扣量解决.rar

2.41 KB, 下载次数: 96, 下载积分: 金币 -3 个

不要问是内裤,还是外裤,内外都是酷!
回复

使用道具 举报

3249

主题

3万

帖子

4万

积分

超级版主

Rank: 21Rank: 21Rank: 21Rank: 21Rank: 21Rank: 21

终身成就奖

发表于 2016-3-26 17:16:41 | 显示全部楼层
哦也,好东西。
深蓝 Thinking软件专题站 www.sLsup.com  —— 接受软件定制与深蓝(Thinking)原创软件的OEM,VIP定制。

大道致简,学以致用。 欲收获,先付出。
回复 支持 反对

使用道具 举报

89

主题

1625

帖子

1913

积分

荣誉会员

Rank: 16Rank: 16Rank: 16Rank: 16

特殊贡献奖

发表于 2016-3-26 20:37:52 | 显示全部楼层
本帖最后由 system1 于 2016-3-26 20:39 编辑

像我这个图中,如何知道是被扣了?看到共享的文件名才知道是什么原因了,感谢
2016-03-26_203751.png
恶意灌水/重复发贴   
回复 支持 反对

使用道具 举报

89

主题

1625

帖子

1913

积分

荣誉会员

Rank: 16Rank: 16Rank: 16Rank: 16

特殊贡献奖

发表于 2016-3-27 11:18:55 | 显示全部楼层
弱弱的问下,把文件直接放到通道里还是要编译成EXE,或是把内容复制到通道的AU3代码里?

点评

可以直接复制到通道,也可以编译EXE 但是360 那个要改 路径  详情 回复 发表于 2016-3-27 15:47
恶意灌水/重复发贴   
回复 支持 反对

使用道具 举报

992

主题

1万

帖子

1万

积分

超级版主

Rank: 21Rank: 21Rank: 21Rank: 21Rank: 21Rank: 21

终身成就奖

 楼主| 发表于 2016-3-27 15:47:05 | 显示全部楼层
system1 发表于 2016-3-27 11:18
弱弱的问下,把文件直接放到通道里还是要编译成EXE,或是把内容复制到通道的AU3代码里?

可以直接复制到通道代码,也可以编译EXE

但是360 那个要改 路径
不要问是内裤,还是外裤,内外都是酷!
回复 支持 反对

使用道具 举报

0

主题

276

帖子

291

积分

青出于蓝(04级)

Rank: 4

发表于 2016-3-27 17:14:16 | 显示全部楼层
这是个好东西要顶
回复 支持 反对

使用道具 举报

14

主题

348

帖子

362

积分

青出于蓝(04级)

Rank: 4

发表于 2016-3-31 18:25:54 | 显示全部楼层
2345也扣量吗?

点评

无盘原因,你没有清理 cookie ,他会认定你 很多台机 为同一台机  详情 回复 发表于 2016-4-1 00:55
回复 支持 反对

使用道具 举报

992

主题

1万

帖子

1万

积分

超级版主

Rank: 21Rank: 21Rank: 21Rank: 21Rank: 21Rank: 21

终身成就奖

 楼主| 发表于 2016-4-1 00:55:26 | 显示全部楼层

无盘原因,你没有清理 cookie ,他会认定你 很多台机 为同一台机
不要问是内裤,还是外裤,内外都是酷!
回复 支持 反对

使用道具 举报

18

主题

348

帖子

411

积分

青出于蓝(04级)

Rank: 4

发表于 2016-4-13 12:56:31 | 显示全部楼层
支持一下 !!!!!!!!!!!!
回复 支持 反对

使用道具 举报

1

主题

78

帖子

82

积分

马马虎虎(03级)

Rank: 3Rank: 3

发表于 2016-5-5 01:58:49 | 显示全部楼层
下下来看下
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

联盟首页|软件下载|联系我们|手机版|小黑屋|纯文字版|网管联盟 ( 粤ICP备17103197号-2 )

GMT+8, 2019-2-24 10:47 , Processed in 0.409431 second(s), 33 queries .

Powered by Discuz! X3.2

© 2001-2013 Comsenz Inc.

快速回复 返回顶部 返回列表